プログレスバー　味はソコソコ？Excel Tips（しお味）

プログレスバーの色々

処理するデータが非常に多く、時間がかかる場合、どの程度処理が進んでいるかイライラしたり、不安になったりする事がありますがそのような場合に、処理の進捗状況を確認出来るようにするのがプログレスバー関係のアイテムの役割です。

プログレスバーに類する様なアイテムとしては以下があります。

●ステータスバーの利用

ステータスバー	設定メニュー	簡易ﾌﾟﾛｸﾞﾚｽﾊﾞｰ

ステータスバーはExcelの最下部に位置して、Excelに関する様々な状態を表示する役割があります。ステータスバーにはいろいろ便利な機能があり（範囲を指定するだけで、様々な統計情報が表示される等々）これを、処理の進行状態を表示する簡易プログレスバーとして使えます。
比較的簡単にプログレスバー的なものが出来ますが、表示が最下部でなおかつ、小さいので少し見にくい欠点があります。

●プログレスバーコントロールの利用

プログレスバー	ｺﾝﾄﾛｰﾙの選択	ﾌﾟﾛｸﾞﾚｽﾊﾞｰｺﾝﾄﾛｰﾙ	toolbox

処理の進捗状況の表示に最も普通に用いられるのが、プログレスバーです。なにか少し時間のかかる処理の場合、様々なアプリ・言語で用いられています。Excelのvbaでも同様なプログレスバーを表示させることが出来ます。デフォルトではプログレスバーコントロールは表示されないので、プログレスバーコントロールの追加の操作を行う必要があります。

●図形の利用
図形のwidthプロパティの値を、処理の進行とともに増加させることによって、バーが横に伸びていく様に表示にできます。

●条件付き書式の利用
excelの条件付き書式の機能を利用して、セルの値を処理の進行とともに増加させる事で、プログレスバー的な表示に出来ます。条件付き書式はvbaで設定すると結構コードが多く、手間がかかるのでマクロの記録で基本的な部分を生成させそれを手直しして使っています。

ステータスバーの利用

ステータスバー

この例は、簡単な計算の進捗状況をセルの範囲とステータスバーに表示させるものです。 1～1000までの数字を1ずつ増加させて、その数値が100の倍数になった毎に、その進捗状況をセルの範囲と下部のステータスバーに表示しています。簡易的に、文字列の■を追加してゆく事でプログレスバー的な表示をさせています。

ステータスバーの利用（標準モジュール）

  Sub statusb()

  Dim fchar As String    '簡易バーグラフ用文字列

  'ステータスバーon
  Application.StatusBar = True

  '自動計算停止
  Application.Calculation = xlCalculationManual

  '/////////////////////////////////////////////////////////////////////////

  For k = 1 To 1000

      'サンプル処理++++++++++++++++++++++++++++++++++++

      If k Mod 100 = 0 Then      'kが100の倍数毎にsを1加算する

          s = s + 1

          Cells(5 + s, 5) = k / 10

      End If


      '++++++++++++++++++++++++++++++++++++++++++++++++

      DoEvents   '割り込み処理の確保

      '+++++++++++++++++++++++++++++++++++++++++++++++++++


      If k Mod 100 = 0 Then      'kが100の倍数毎に簡易バーグラフにワンブロック"■"を1つ追加する

         fchar = fchar + "■"

      End If

      Application.StatusBar = "進捗状況(%)：" & Format(k / 10, "###.0") & fchar

      DoEvents   '割り込み処理の確保

  Next

  '/////////////////////////////////////////////////////////////////////////

  MsgBox "処理が完了しました。"


  'データクリア
  Range(Cells(5, 5), Cells(15, 5)).ClearContents

  'ステータスバーoff
  Application.StatusBar = False
  '自動計算再開
  Application.Calculation = xlCalculationAutomatic

ステータスバーを利用して簡易的なプログレスバーを表示させるサンプル（ダウンロード）

プログレスバーコントロールの利用

プログレスバー

プログレスバーを利用するには、そのプログレスバーコントロールをアクティブにする必要があります。

excelメニュー

1）[開発タブ]->[デザインモード選択][挿入モード選択]->コントロールの選択boxで工具マークをクリック

2）コントロールの選択BOXが表示されるので「Microsoft　Progressbar　Contorol」を選択

3）ツールboxにプログレスバーコントロールが表示される

プログレスバーは良く目につくように通常、サブフォームによるダイアログを出して、そこにプログレスバーを設置します。今回もその標準的な構成にしています。

ｺﾝﾄﾛｰﾙの選択	ﾌﾟﾛｸﾞﾚｽﾊﾞｰｺﾝﾄﾛｰﾙ	toolbox	ｻﾌﾞﾌｫｰﾑの作成

プログレスバーコントロールの利用（標準モジュール）

  Sub progressf()

  Dim s As Integer
  Dim ds As Worksheet        'ワークシート
  Dim fchar As String        'ステータスバーでの進捗表示用

  '処理選択用フラグ

  Set ds = Worksheets("progress")

  '自動計算停止
  Application.Calculation = xlCalculationManual

  '//////プログレスバーFormを表示////////////////////////////////////////

    'プログレスバーの表示
    UserForm1.Show vbModeless
    UserForm1.Repaint

    'プログレスバーの最小値を設定
    UserForm1.ProgressBar1.Min = 0

    'プログレスバーの最大値を設定
    UserForm1.ProgressBar1.Max = 1000

    'プログレスバーの現在値を設定
    'processf1.ProgressBar1.value =


  '/////////////////////////////////////////////////////////////////////////

  For k = 1 To 1000

      'サンプル処理++++++++++++++++++++++++++++++++++++

     ' s = (k + 1) / 100

      If k Mod 100 = 0 Then

          s = s + 1

          ds.Cells(5 + s, 5) = k / 10

      End If

    '+++++++++++++++++++++++++++++++++++++++++++++++++++

      DoEvents   '割り込み処理の確保

    '+++++++++++++++++++++++++++++++++++++++++++++++++++

      UserForm1.ProgressBar1.Value = k  'プログレスバー用の入力

    '+++++++++++++++++++++++++++++++++++++++++++++++++++

  Next

  '////////////////////////////////////////////////////////////////////////////////////////


  MsgBox "処理が完了しました。"

  '終了処理

     UserForm1.Hide
     Unload UserForm1

  'データクリア
  Range(Cells(5, 5), Cells(15, 5)).ClearContents


  '自動計算再開
  Application.Calculation = xlCalculationAutomatic


  End Sub

プログレスバーコントロールを利用してプログレスバーを表示させるサンプル（ダウンロード）

図形の利用

図形の利用

図形のwidthプロパティの値を、処理の進行とともに増加させることによって、バーが横に伸びていく様に表示にできます。この例ではワークシート上に図形を設置しましたが、プログレスバーコントロールの利用の時の様にサブフォームに設置することも出来ます。

図形の利用によるプログレスバーの例

  Sub progressf()

  Dim s As Integer
  Dim zLeft As Variant       '図形の設置位置（左）
  Dim zTop As Variant        '図形の設置位置（上）
  Dim frange As Range        '図形の設置位置のレンジ
  Dim ds As Worksheet        'ワークシート

  '処理選択用フラグ

  Set ds = Worksheets("progress")

  '自動計算停止
  Application.Calculation = xlCalculationManual

  '///////図形の設置と性状の設定//////////////////////////////////////////

    Set frange = Range("g4")

    zLeft = frange.Left + 1
    zTop = frange.Top + 1

    With ActiveSheet.Shapes.AddShape(msoShapeRectangle, zLeft, zTop, 1, 17)

      '名前を指定
      .Name = "pbox2"

      '図形の詳細を設定
      .Fill.ForeColor.RGB = RGB(100, 200, 255)
      .Fill.Transparency = 0.5
      .Line.ForeColor.RGB = RGB(255, 255, 255)

    End With

  '/////////////////////////////////////////////////////////////////////////

  For k = 1 To 1000

      'サンプル処理++++++++++++++++++++++++++++++++++++

     ' s = (k + 1) / 100

      If k Mod 100 = 0 Then
          s = s + 1

          ds.Cells(5 + s, 5) = k / 10

      End If

      '++++++++++++++++++++++++++++++++++++++++++++++++

      DoEvents   '割り込み処理の確保

      '++++++++++++++++++++++++++++++++++++++++++++++++

     If k Mod 100 = 0 Then

      ds.Shapes("pbox2").Width = k / 10
      DoEvents  '割り込み処理確保

     End If

     DoEvents '割り込み処理確保

  Next

  '///////////////////////////////////////////////////////////////////////////////

  MsgBox "処理が完了しました。"

  '終了処理
  '図形の削除
  ActiveSheet.Shapes("pbox2").Delete

  'データクリア
  Range(Cells(5, 5), Cells(15, 5)).ClearContents

  '自動計算再開
  Application.Calculation = xlCalculationAutomatic


  End Sub

図形を利用してプログレスバーを表示させるサンプル（ダウンロード）

条件付き書式の利用

共通サンプル

Excelの機能に「条件付き書式」があり、セルごとにある条件下の色の変化、簡易バー表示等々様々な動的な書式を設定する機能がありますが、そのうちの簡易バー表示（セル内の数値に対応してそのセル内にバー状の領域を表示させる機能）を用いてプログレスバーを出来ないかやってみました。
条件付き書式はvbaで設定すると、コード的に量が多いのでここはマクロの記録で自動生成させてそれを手直しして使っています。コードを整理するためその部分は別モジュールのサブルーチンにしてあります。

条件付き書式の利用の例（メイン部分）

  Sub progressf()

  Dim ds As Worksheet        'ワークシート
  Dim dflg(5) As Variant     '処理の判別用フラグ
  Dim fchar As String        'ステータスバーでの進捗表示用

  '処理選択用フラグ

  Set ds = Worksheets("progress")


  '///////条件付き書式の設定//////////////////////////////////////////////


      Call setcdc


  '/////////////////////////////////////////////////////////////////////////

  For k = 1 To 1000

      'サンプル処理++++++++++++++++++++++++++++++++++++

     ' s = (k + 1) / 100

      If k Mod 100 = 0 Then

          s = s + 1

          ds.Cells(5 + s, 5) = k / 10

      End If

      '++++++++++++++++++++++++++++++++++++++++++++++++

      DoEvents   '割り込み処理の確保

     '+++++++++++++++++++++++++++++++++++++++++++++++++

      Cells(6, 7) = k

      DoEvents  '割り込み処理確保

  Next


  '////////////////////////////////////////////////////////////////////////////////////////


  MsgBox "処理が完了しました。"

  '終了処理

  '条件付き書式のクリア****************************************

  Cells.FormatConditions.Delete

  '************************************************************


  'データクリア
  Range(Cells(6, 5), Cells(15, 5)).ClearContents
  Cells(6, 7) = ""


  End Sub

条件付き書式の設定（サブルーチン部分）

  Sub setcdc() '■■■条件付き書式設定■■■（条件付き書式の設定）

      Range("G6").Select

      Selection.FormatConditions.AddDatabar
      Selection.FormatConditions(Selection.FormatConditions.Count).ShowValue = True
      Selection.FormatConditions(Selection.FormatConditions.Count).SetFirstPriority

      With Selection.FormatConditions(1)
          .MinPoint.Modify newtype:=xlConditionValueNumber, newvalue:=0
          .MaxPoint.Modify newtype:=xlConditionValueNumber, newvalue:=1000
          .BarFillType = xlDataBarFillSolid
          .Direction = xlContext
          .NegativeBarFormat.ColorType = xlDataBarColor
          .BarBorder.Type = xlDataBarBorderNone
          .AxisPosition = xlDataBarAxisAutomatic
          .BarColor.Color = 13012579
          .BarColor.TintAndShade = 0
          .AxisColor.Color = 0
          .AxisColor.TintAndShade = 0
          .NegativeBarFormat.Color.Color = 255
          .NegativeBarFormat.Color.TintAndShade = 0

      End With

  End Sub

プログレスバー_条件付き書式の利用サンプル（ダウンロード）

プログレスバーの色々のまとめ（総まとめ）

以上のTIPSをまとめた共通サンプルファイルです。
4種類のプログレスバーの動きを実際に試せます。

プログレスバーの色々のまとめ（総まとめ）ダウンロード