ファイルの読み込み　味はソコソコ？Excel Tips（しお味）

ファイルの読み込み

元々、ファイルの読み込みはVBAアプリの基本中の基本で、多くのVBAアプリでその機能が備わっています。
基本的な処理の流れとしては、読み込むファイルを指定するためのダイアログを出して、ファイルを選択したのちその後の処理に繋がっていきます。（場合によりダイアログなしで直接決め打ちで読み込む場合もあります）

ファイルの読み込み等の操作に、用いるのが
GetOpenFilenameメソッドで記述は以下のとおり
Application.GetOpenFilename(FileFilter, FilterIndex, Title, ButtonText, MultiSelect)
詳細は
https://docs.microsoft.com/ja-jp/office/vba/api/excel.application.getopenfilename

ファイルを読み込むためのダイアログ

とりあえず、ダイアログを出してなにか処理したいファイルを指定するまでの超基本的な部分を示します。取り扱いたいファイルには色々な種類のものがありますが、下記のコードの中で("全てのファイル,*.*")の部分を

("全てのファイル,*.*")：全てのファイル
("Excel,*.xlsx")：Excelファイル
("CSVファイル,*.csv")：全てのファイル

等々に変えることにより、取り扱うファイルの種類を限定することが出来ます。
以下、そのコードになります。

  Sub openfile()

　 Dim rdfile As Variant   'ファイルパス＆ファイル名 キャンセル時にboolean変数に対応のためstringでなくてvariantとする

  rdfile = Application.GetOpenFilename("全てのファイル,*.*")
    If VarType(rdfile) = vbBoolean Then
          MsgBox "キャンセルされました"
          Exit Sub  '処理中止
          Else
                    '処理進行
    End If

  '次の処理～

  End Sub

ファイルを読み込むダイアログ（ダウンロード）

ファイルを読み込んで所定のシートに貼り付ける操作

ファイルを読み込む	------->	RDATAシートに貼り付ける

もう少しすすめて、このサンプルではファイルを読み込んでから、特定のシート「RDATA」に貼り付けるまでをしています。処理の流れとしては、

1）取り込む対象ファイルのパス、ファイル名を取得します。
2）その情報から取り込むファイルを開いてその内容をクリップボードにコピーします。
3）貼り付け側のシートにその内容を貼り付けます。
4）クリップボードの内容をクリアします。元のファイルを閉じます。

一旦、シートに取り込めば、データのチェック・・・とか、フォーマットの変換・・・とかあとは本来の目的である様々な処理に進む事になります。
以下、そのコードになります。

  Sub file_read_paste()

      Dim rdfile As Variant   'ファイルパス＆ファイル名 キャンセル時にboolean変数に対応のためstringでなくてvariantとする
      Dim PathName As String  'ファイルパス
      Dim FileName As String  'ファイル名
      Dim pos As Long         'パス分離用
      Dim fnamechr As String  'このファイルの名前収容


   fnamechr = ActiveWorkbook.Name   'このファイル名取得

   rdfile = Application.GetOpenFilename("全てのファイル,*.*")    'ファイル選択ダイアログを出す

        'ダイアログのキャンセルを押した場合の処理
         If VarType(rdfile) = vbBoolean Then  'キャンセルを押した場合の処理　Application.GetOpenFilenameがboolean変数(false）を返す

               MsgBox "キャンセルされました"
               Exit Sub  '処理中止

         End If

      Workbooks.Open rdfile                               '元ファイルを開く**********************

      pos = InStrRev(rdfile, "\")                         'InStrRev 関数は、文字列の後ろから指定の文字列を検索し、最初に見つかった位置を返します。

      PathName = Left(rdfile, pos)                        'ファイルのパス取得
      FileName = Mid(rdfile, pos + 1)                     '対象ファイル名取得

      'データのコピー元の準備
      Windows(FileName).Activate                          '対象のファイルをActiveに
      Cells.Select                                        '全ての範囲を取り込み
      Selection.Copy                                      'コピーする

      'データのコピー先の準備
      Windows(fnamechr).Activate                          'このファイル自身のファイルをActiveに

      Sheets("RDATA").Activate                            'RDDATAシートをActiveに
      Sheets("RDATA").Select                              'RDDATAシートを選択

      Sheets("RDATA").Range("A1").Select                  'シートのA1：(1,1)の部分にペースト
      ActiveSheet.Paste
      Sheets("RDATA").Cells(1, 1).Select                  'カレントカーソルをA1：(1,1)に

      Excel.Application.CutCopyMode = False               'クリップボードのクリア
      Windows(FileName).Close                             '元ファイルを閉じる*******************


    '読み込みファイル情報の表示

      '最終行,最終列の取得UsedRangeの範囲で空でないデータを検索、一番外側のデータ、Rowﾌﾟﾛﾊﾟﾃｲ:使用行､Colmnﾌﾟﾛﾊﾟﾃｲ：使用列

      Sheets("RDATA").Activate


  End Sub

ファイルを開いて貼り付ける処理（ダウンロード）

一度に複数のファイル情報を読み込み、そのパスとファイル情報を取得する

複数ファイルを読み込む	------->	各ファイルの情報を表示

この処理は、複数のファイルの情報を一括で取得します。複数のファイルを連続的に一定の処理をする場合の、前段階の処理です。

GetOpenFilenameメソッドのMultiSelectのパラメーターをMultiSelect:=True とすることで複数ファイルの読み込みが出来るようになります。
Application.GetOpenFilename(FileFilter, FilterIndex, Title, ButtonText, MultiSelect)

以下、そのコードになります。

  Sub mfpathget()    '複数ファイル情報の取り込み/////////////////////////////////////////

      Dim mFile As Variant   'ダイアログ情報の収容変数
      Dim i As Long


      'ファイル取り込みダイアログ表示　MultiSelect:=True　複数選択可**********
      mFile = Application.GetOpenFilename(FileFilter:="全てのファイル (*.*),*.*; *.*", MultiSelect:=True)


         If VarType(mFile) = vbBoolean Then  'TRUE FALSE　キャンセルを押した時の処理：Booleanが戻り値

             MsgBox "キャンセルされました"

             Exit Sub

         End If


      '取り込みファイル数のチェック******************************************
      If UBound(mFile) > 100 Then

               MsgBox "一度の取り込みファイル数は100件までです"

               Exit Sub  '処理終了

             Else

      End If

      '情報書き込み領域の初期化*********************************************
      Worksheets("RDATA").Cells.Clear


      'ファイル情報書き出し*************************************************
      For i = 1 To UBound(mFile)

          Worksheets("RDATA").Cells(i, 1) = mFile(i)
          Worksheets("RDATA").Cells(i, 10) = FileLen(mFile(i))
          Worksheets("RDATA").Cells(i, 11) = FileDateTime(mFile(i))



      Next i

      Worksheets("RDATA").Select

      MsgBox "ファイル情報取得完了"


  End Sub

複数ファイル情報を一括取得する1（ダウンロード）

この場合、ファイルの情報をFileLen、FileDateTime関数で取得していますが、2Ｇ以上のファイルサイズは正確に取得出来ないので FileSystemObjectを利用します。
その利用方法はVBE(vbaの開発環境の事です）の開発画面で
「ツール」-->「参照設定」で参照設定のダイアログがでるので、その中の「Microsoft Scripting Runtime」にチェックを入れて「OK」ボタンを押す。これで準備が出来ました。

（定番の記述例）
Dim mFile As Variant----------------->ダイアログ情報の収容変数の定義
Dim fso As FileSystemObject-------->ファイルシステムオブジェクト変数の定義
Dim f As File ------------------------->ファイルオブジェクト変数の定義
Set fso = New FileSystemObject
（FileSystemObjectオブジェクトクラスを実際に利用出来るようにします：ｲﾝｽﾀﾝｽ化）
Set f = fso.GetFile(mFile(i)) --------->ファイル情報収容
実際のファイル情報＝f.各種プロパティ

以下、そのコードになります。

  Sub mfpathget()    '複数ファイル情報の取り込み////２Ｇ以上のファイルサイズ情報の取得/////////////////////////////////////

      Dim mFile As Variant   'ダイアログ情報の収容変数
      Dim i As Long
      Dim ws As Worksheet
      'Dim ipath As String　 '初期パスの収容

      Set ws = Worksheets("RDATA")  'シート名

     'FileSystemObjectの利用の場合
      Dim fso As FileSystemObject
      Set fso = New FileSystemObject 'FileSystemObjectオブジェクトクラスを実際に利用出来るようにします（インスタンス化）

      Dim f As File           'ファイルオブジェクト
      Dim d As Date           '日付変数
      Dim d2 As Date          '日付変数

      'ipath = Worksheets("sheet1").Cells(6, 4)      '取り込み用初期設定パス取得
      'ChDir ipath                                   'パスのとおりデイレクトリ移動


      'ファイル取り込みダイアログ表示　MultiSelect:=True　複数選択可**********
      mFile = Application.GetOpenFilename(FileFilter:="全てのファイル (*.*),*.*; *.*", MultiSelect:=True)

         If VarType(mFile) = vbBoolean Then  'TRUE FALSE　キャンセルを押した時の処理：Booleanが戻り値

             MsgBox "キャンセルされました"

             Exit Sub

         End If


      '取り込みファイル数のチェック********UBound:（配列の最大インデックスを返す関数）******
      If UBound(mFile) > 100 Then

               MsgBox "一度の取り込みファイル数は100件までです"

               Exit Sub  '処理終了

             Else

      End If

      '情報書き込み領域の初期化*********************************************
      Worksheets("RDATA").Cells.Clear


      'ファイル情報書き出し*************************************************
      For i = 1 To UBound(mFile)

          ws.Cells(i, 1) = mFile(i)                  'フルパス付ファイル名
          ws.Cells(i, 10) = FileLen(mFile(i))        'Filelen関数によるファイルサイズ
          ws.Cells(i, 11) = FileDateTime(mFile(i))   'FileDateTime関数によるファイルの日付

          'ファイル関係の情報取得にはFileSystemObjectの利用が必要です

          '「ツール」-＞「参照設定] Microsoft Scripting Runtime をチェックして [OK]
          Set f = fso.GetFile(mFile(i))                      'ファイル情報収容

          ws.Cells(i, 12) = CStr(f.Size)    'ファイルサイズの表示　ファイルオブジェクト「ｆ」のsizeプロパテイ

          d = f.DateCreated
          ws.Cells(i, 13) = d               'ファイル作成日の表示　ファイルオブジェクト「ｆ」のDateCreatedプロパテイ

          d2 = f.DateLastModified
          ws.Cells(i, 14) = d2              'ファイル最終更新日の表示　ファイルオブジェクト「ｆ」のDateLastModifiedプロパテイ

      Next i

  '表示項目
       ws.Cells(i + 2, 1) = "ファイル名（フルパス付）"

       ws.Cells(i + 2, 10) = "ファイルサイズ(ﾊﾞｲﾄ)"
       ws.Cells(i + 3, 10) = "FileLen関数"

       ws.Cells(i + 2, 11) = "ファイルの日付"
       ws.Cells(i + 3, 11) = "FileDateTime関数"

       ws.Cells(i + 2, 12) = "ファイルサイズ(ﾊﾞｲﾄ)"
       ws.Cells(i + 3, 12) = "sizeﾌﾟﾛﾊﾟﾃｲ"

       ws.Cells(i + 2, 13) = "ファイルの作成日"
       ws.Cells(i + 3, 13) = "DateCreatedﾌﾟﾛﾊﾟﾃｲ"

       ws.Cells(i + 2, 14) = "ファイルの最終更新日"
       ws.Cells(i + 3, 14) = "DateLastModifiedﾌﾟﾛﾊﾟﾃｲ"


      ws.Select

      MsgBox "ファイル情報取得完了"


  End Sub

複数ファイル情報を一括取得する2（ダウンロード）

ファイルの読み込み等の操作まとめのＴＩＰＳファイル
以上のTIPSをまとめたファイルです。お時間の無い方におまとめ編です。この場合あらかじめのファイルパスの設定等の機能もありますので個々のパソコンの環境に合わせて設定を変えてください。

このExcelファイルの中にも、個々の説明があります。参考にしてください。

TIPS_ファイルの読み込み（まとめ）